function ResetPTs(PlayerController Sender)
{
	local RPGStatsInv StatsInv;
	local Inventory Inv, NextInv;
	local int i;

	if (RPG == None)
	{
		Sender.ClientMessage("You must use this within a UT2004RPG enabled game.");
		return;
	}

	//first, find the current statsinv
	if (Sender.Pawn != None && !Sender.Pawn.IsA('xPawn'))
	{
		Sender.ClientMessage("You must be either dead or outside of a vehicle.");
		return;
	}

	StatsInv = FindStatsInvFor(Sender);
	if (StatsInv == None)
	{
		Sender.ClientMessage("Crucial information not found.  Reconnect and try again.");
		return;
	}

	if (Sender.Pawn != None)
	{
		Sender.Pawn.HealthMax = Sender.Pawn.default.HealthMax;
		Sender.Pawn.SuperHealthMax = Sender.Pawn.default.SuperHealthMax;
		if (Sender.Pawn.Health > Sender.Pawn.HealthMax)
			Sender.Pawn.Health = Sender.Pawn.HealthMax;

		Sender.AdrenalineMax = Sender.default.AdrenalineMax;
		if (Sender.Adrenaline > Sender.AdrenalineMax)
			Sender.Adrenaline = Sender.AdrenalineMax;

		Inv = Sender.Pawn.Inventory;
		while (Inv != None && i < 200)
		{
			i++;

			NextInv = Inv.Inventory;

			if (AdrenRegenInv(Inv) != None ||
				AmmoRegenInv(Inv) != None ||
				GhostInv(Inv) != None ||
				RegenInv(Inv) != None)
				Inv.Destroy();

			Inv = NextInv;
		}
	}

	StatsInv.DataObject.WeaponSpeed = 0;
	StatsInv.DataObject.HealthBonus = 0;
	StatsInv.DataObject.AdrenalineMax = 100;
	StatsInv.DataObject.Attack = 0;
	StatsInv.DataObject.Defense = 0;
	StatsInv.DataObject.AmmoMax = 0;
	StatsInv.DataObject.Abilities.Remove(0, StatsInv.DataObject.Abilities.Length);
	StatsInv.DataObject.AbilityLevels.Remove(0, StatsInv.DataObject.AbilityLevels.Length);
	StatsInv.ClientResetData();

	RPG.ValidateData(StatsInv.DataObject);

	//update the struct containing the info copied to the client
	StatsInv.DataObject.CreateDataStruct(StatsInv.Data, false);

	//update the pawn's info to update
	Level.Game.BaseMutator.ModifyPlayer(Sender.Pawn);

	Sender.ClientMessage("Your stat points have been reset.");
}